startsida < företaget < organis. < datorer < frågor
 
Tid och datum

 
  Frågor och svar
Allmänt
Tabeller
Kalkylering 1
Kalkylering 2
Text och format
Tid och datum
Tekniska problem
   
  Innehåll
expowera

 

Materialet publicerat med tillstånd från Dennis Wallentin.

F: Jag vill tillåta användarna att ange tid såsom 1400 istället för 14:00 men samtidigt redovisa tiden i tidsformatet 00:00?

S: Antag följande:

A2 = 1400
B2 = 1800
C2 =TEXT(B2;"0\:00")-TEXT(A2;"0\:00")

med tidsformatet tt:mm så ger det resultatet 04:00.


F: Från ett stordatorsystem erhåller jag följande tidsuttryck 00:04:30:00 (DD:TT:MM:SS) - Hur ska jag göra för att omvandla det till decimaltid såsom 4,5?

S: Enklast är att omvandla det mha följande formel:
=TIDVÄRDE(HÖGER(E8;8))*24


F: Är det möjligt att få fram det äldsta datumet i en datumserie?

S: Jo, det är fullt möjligt med följande formel:
=MIN(A2:A4)

Finns det felvärden kan följande matris-formel användas:
{=MIN(OM(ICKE(ÄRFEL(A2:A4));A2:A4))}

Här måste vi också datumformatera cellen.


F: I en cell anges födelsedatumet, åååå-mm-dd, och nu vill jag räkna fram hur gammal personen ifråga är?

S: Två möjliga formellösningar finns att tillgå:
=ÅRDEL(IDAG();B10)
och
=DATEDIF(B10;IDAG();"y")&" år "&DATEDIF(B10;IDAG();"ym")&" månader."


F: I en kolumn har jag datum. Nu vill jag "avrunda" datumen enligt följande:

- Datum < 15:e i varje månad ska visas som år-månad-15

- Datum > 15:e i varje månad ska visas som år-månad-sista datumet.

S: Formeln nedan ger en lösning och resultatcellerna formateras med ett datumformat:
=OM(DAG(B1)<15;DATUM(ÅR(B1);MÅNAD(B1);15);DATUM
(ÅR(B1);MÅNAD(B1)+1;0))


F: Vilket tidsformat kan jag använda mig av för att räkna med minuter, sekunder och hundradelar?

S: Följande anpassade tidsformat löser problemet: mm:ss,00


F: I cell C6 anges startdatumet för projektet och i cell C7 slutdatumet. Hur ska jag göra så att startmånaden alltid räknas med?

S: Följande formel löser problemet ifråga:
=DATEDIF(ÅR($C$6)&"-"&MÅNAD($C$6)&"-01";ÅR($C$7)&"-"&
MÅNAD($C$7)&"-01";"m")+1


F: Hur kan jag få fram t ex antal måndagar som har passerat fr o m årsskiftet tills nu?

S: Jo, det går att räkna fram mha följande matrisformel:
{=SUMMA(OM(VECKODAG(RAD(INDIREKT(DATUM(ÅR(IDAG());1;1)
&":"&IDAG()));2)=1;1))}


F: Vilket format ska jag använda mig av för att få datum och veckodag i en och samma cell, såsom "2001-10-22 Måndag"?

S: Enklast är följande format:
ÅÅÅÅ-MM-DD* DDDD


F: I en cell har jag datum och tidsangivelse. Hur ska jag göra för att få fram antal timmar?

S: Det går att lösa enligt följande exempel:

Cell A1: 2001-06-11 09:00

Cell B1:
=TIMME(A1)/24

Vill du endast ha minuter används följande formel:
Cell B1: = MINUT(A1)/(24*60)

Cellen B1 formaterats med tidsformatet: tt:mm


F: Hur ska jag göra för att räkna ut tidsdifferensen i timmar mellan två datum med tid?

S: Antag att vi har följande förutsättningar:
A1: 2001-06-01 13:50:00
B1: 2001-06-30 16:49:00

I cell C1 anges följande formel: B1-A1 och formatera C1 med tidsformatet: [tt].mm


F: Jag behöver automatiskt erhålla nästkommande lördags datum.

S: Försök med följande formel:
=IDAG()+7-VECKODAG(IDAG())

Om IDAG är en lördag så returneras datumet för den lördagen.


F: Jag har i en arbetsblad datum- och tidsangivelse tillsammans, såsom 2001-02-27 13:30. Jag vill nu separera uttrycken från varandra.

S: Antag att värdet finns i cellen A1:

För datumangivelse:
=DATUM(ÅR(A1);MÅNAD(A1);DAG(A1))

För tidsangivelse:
=KLOCKSLAG(TIMME(A1);MINUT(A1);SEKUND(A1))

Se till att cellformatet är tt:mm:ss


F: Hur kan jag förhindra att användare matar in andra månader än innevarande månad?

S: Använd Dataverifiering och följande formel:
=MÅNAD(C3)=MÅNAD(NU())

Där cellreferensen utgör den första cellen i området.


F: Jag vill kunna räkna fram genomsnittlig tid per mil för en viss distans?

S: Antag att vi har Distans i cell A1 och Tid (med formatet tt:mm:ss) i cell B1. Då kan vi lösa det mha följande formel:
=(B1*24)/(A1*24)

Formatera formelcellen till ett tidsformat.


F: Jag har ett arbetsblad med ifyllda datum och har ändrat till Macintosh Datumsystem. Nu visar alla celler fel datum???

S: Använder vi oss av Macintosh Datumsystem för redan ifyllda datumvärden är det riktigt att datumvärdena ändras. Det ordinarie datumsystemet börjar 1900-01-01 medan Macintosh börjar såsom 1904-01-02

Skillnaden mellan datumsystemen uppgår till 1462 dagar, vilket vi måste ta hänsyn till. För att få rätt datum måste vi dra ifrån dessa dagar från det "nya" datumet. Enklast är att i en intilliggande cell ange:
=A1-1462

Ändrar vi datumsystem och anger därefter datum påverkas inte dessa av ändringen.


F: Jag vill summera minuter och sekunder men när värdet överstiger 60 minuter får jag timmar - Jag vill bara ha minuter och sekunder!

S: Genom att använda oss av tidsformatet [mm]:ss förhindrar vi XL att överträda gränsen för timmar och kan då få t ex 88 minuter.


F: Jag vill kunna ange ett datum såsom 14/1 och i cellen erhålla Sö 14/1.

S: Här kan vi använda oss av följande datumformat:
DDDD D/M


F: Utifrån ett datum vill jag få fram föregående månad - hur gör jag?

S: Du kan använda dig av följande formler

=DATUM(ÅR(A1);MÅNAD(A1)-1;1)
eller
=EDATUM(A1;-1)

och formatera cellen till ett datumformat.


F: Jag ska lägga till 10 dagar för ett datum men vill också försäkra mig om att det alltid är en arbetsdag. Har du något tips?

S:Använd funktionen:
=ARBETSDAGAR(A1;10)


F: Hur räknar jag ut sluttid, där jag har angivit start- och stopptid?

S: Det kan med följande formler:

=OM(Starttid>Stopptid;1-(Starttid-Stopptid);Stopptid-Starttid)
och
=OM(Starttid>Stopptid;"24:00"-(Starttid-Stopptid); Stopptid-Starttid)

Båda formler klarar av större tidsdifferenser än 24 timmar.


F: Vid import får jag textsträngar med datum, såsom 20000210. Jag vill konvertera dessa till riktiga datum!

S: Mata in följande formel:
=TEXTNUM(VÄNSTER(A1;4)&"-"&EXTEXT(A1;5;2)&"-"&EXTEXT(A1;7;2))

I nästa steg formateras cell till ett datumformat.


F: Hur får jag utifrån födelsedatumet fram personens 65-årsdag?

S: Genom att addera 65 till födelseåret enligt följande:
=DATUM(ÅR(A1)+65;MÅNAD(A1);DAG(A1))


F: Hur får jag enklast reda på vilken dag på året som ett visst datum har?

S: Jo, mha följande formel:
=A11-DATUM(ÅR(A11)-1;12;31)

där A11 innehållet datumet samt formatera cell(erna) till tal.


F: Hur kan jag få fram ålder utifrån personnumren med formatet 7202021010?

S:
=ÅR(NU())-EXTEXT(19&B3;1;4)

Formeln fungerar både för 1900 och 2000.


F: Hur kan man räkna fram antal arbetsdagar och antal arbetstimmar, såsom mellan 2000-01-03 08:00 och 2001-01-17 16:30?

S: Antag att antal arbetstimmar uppgår till 8 timmar för varje arbetsdag. Antag vidare att arbetstiden är förlagd mellan 08:00 till 16:00.

Nedanstående fula formel ger resultatet 11 dagar och 0,5 timmar:
=OM(HELTAL(A1)=HELTAL(B1);"0 dagar"&AVRUNDA(24*(B1-A1);2)&"
och timmar"; MAX(NETTOARBETSDAGAR(A1+1;B1-1);0)
+HELTAL(((24*((B1-HELTAL(B1)))-(24*(A1-HELTAL(A1))))+8)/8)& " dagar och "
&REST(AVRUNDA(((24*(B1-HELTAL(B1)))-8)+(16-(24*(A1-HELTAL(A1))));2);8) &" timmar ")


F: Jag vill räkna fram antal förekomster av tider inom ett givet intervall, t ex mellan 03:00 och 07:00 - hur gör jag?

S: Även om det här avser tid så kan man använda sig av formeln:
=ANTAL.OM(A1:A3;">=03:00")-ANTAL.OM(A1:A3;">07:00")

Tidsuttrycken i formeln kan ersättas av cellreferenser. Man får dock formatera resultatcellen till tal.


F: Jag vill konvertera t ex 19991110 till XL:s datumformat för att kunna utföra beräkningar - hur gör jag?

S: Jo, det kan lösas mha följande formel:
=DATUM(VÄNSTER(A1;4);EXTEXT(A1;5;2);HÖGER(A1;2))


F: Jag vill konvertera numeriska tal till tid, t ex 74 sekunder ska omvandlas till 1:14 (1 minut och 14 sekunder).

S: I XL sparas tid som en del av 24 timmars cykler. För att arbeta med timmar krävs en faktor om 24, för minuter 1440 (24*60) och för sekunder 86400 (24*60*60). För att omvandla tal till tid måste tal divideras med önskad tidsuttryck: =74/86400 och formateras som tid -----> 00:01:14. Vill man gå åt det andra hållet, dvs omvandla tidsuttryck till tal krävs multiplikation: =00:01:14*86400 och formateras som tal ------> 74.


F: Hur gör jag för att ange nästa dags datum och veckodag?

S:För att erhålla datum använd:
=NU+1 och datumformatera cellen.

För att få fram nästa veckodag, ej lördagar eller söndagar:
=INITIAL(TEXT(NU()+VÄLJ(VECKODAG(NU());1;1;1;1;1;3;2);"DDDD"))


F: Jag vill få fram första datumet i månaden, t ex 1999-10-01, utan att behöva ange någon uppgift!

S: Ingeting är omöjligt i XL! Pröva:
=DATUM(ÅR(IDAG());MÅNAD(IDAG());1)


F: Vid import vill jag kunna ändra datumangivelsen från 19990913 till 99-09-13.

S: Skriv in följande formel i en ny kolumn och kopiera den så långt det behövs:
=EXTEXT(A1;3;2)&"-"&EXTEXT(A1;5;2)&"-"&HÖGER(A1;2)


F: Jag har klockslag i en kolumn och nu vill jag lägga till 2 timmar för varje klockslag i en annan kolumn - hur gör jag?

S: Anta att du i cellen A1 har värdet 13:45 så kan du använda dig av följande formel: =A1+2/24.

Alternativt kan du använda formeln:
=A1+KLOCKSLAG(2;0;0).

Glöm inte att formatera målcellerna till ett tidsformat, t ex "tt:mm".


F: Hur kan jag lägga till månader till ett datum?

S: Anta att ett datum finns i cellen A1 och att 1 månad ska läggas till så kan man i cellen B2 skriva in följande formel:
=DATUM(ÅR(A1);MÅNAD(A1)+1;DAG(A1))


F: Jag använder mig av NU-funktionen men vill få datumet som 99-08-03.

S: M h a TEXT-funktionen kan det lösas:
=TEXT(NU();"ÅÅ-MM-DD")


F: Jag behöver få fram antal kvarvarande dagar på ett år - hur gör jag?

S: Om vi antar att ett datum, t ex 1999-07-27 finns angivet i cellen A1 så kan följande formel användas:
=DATUM(ÅR(A1);12;31)-A1.

Se till att formatera cellen med formeln till ett annat format än datum!


F: Hur ska jag göra för att få fram antal veckor för en given period?

S: Använd dig av följande formel:
=TEXT((DATEDIF(startdatum;slutdatum;"D")/7);"0,00")


F: Jag behöver konvertera datum till dag och månad, t ex 1999-07-01 ska bli 7 juli.

S: M h a TEXT-funktionen kan problemet lösas:
=TEXT(A1;"D MMMM").

Upp
Senast uppdaterad: 2005-10-05 © Dennis Wallentin